EABI

內核裡面談EABI,OABI,其實相對於系統調用的方式，當然我們所說的系統限於arm系統。

什麼是EABI?

Embedded application binary interface, 即嵌入式應用二進位介面，是描述可連接目標代碼，庫目標代碼，可執行文件映像，如何連接，執行和調試，以及目標代碼生成過程，和c, c++語言介面的規範，是編譯連接工具的基礎規範，也是研究它們工作原理的基礎，可惜arm的EABI迄今為止沒有完全訂好。作為EABI的組成部分有過程調用規範，可執行文件格式規範，c/c++ ABI規範和調試格式規範。

EABI ,說的是這樣的一種新的系統調用方式

mov r7, #num

swi 0x0

原來的系統調用方式是這樣，

swi (#num | 0x900000) (0x900000是個magic值)

也就是說原來的調用方式(Old ABI)是通過跟隨在swi指令中的調用號來進行的，現在的是根據r7中的值。

現在看兩個宏，一個是

CONFIG_OABI_COMPAT 意思是說和old ABI兼容

另一個是

CONFIG_AEABI 意思是說指定現在的方式為EABI

這兩個宏可以同時配置，也可以都不配，也可以配置任何一種。

我說一下內核是怎麼處理這一問題的。

我們知道，sys_call_table 在內核中是個跳轉表，這個表中存儲的是一系列的函數指針，這些指針就是系統調用函數的指針，如(sys_open).系統調用是根據一個調用號（通常就是表的索引）找到實際該調用內核哪個函數，然後運行該函數完成的。

首先，對於old ABI,內核給出的處理是給它建立一個單獨的system calltable,叫sys_oabi_call_table，這樣，兼容方式下就會有兩個system call table, 以oldABI方式的系統調用會執行old_syscall_table表中的系統調用函數，EABI方式的系統調用會用sys_call_table中的函數指針。

配置無外乎以下4中

第一 兩個宏都配置 行為就是上面說的那樣

第二 只配置CONFIG_OABI_COMPAT ，那麼以old ABI方式調用的會用sys_oabi_call_table，以EABI方式調用的 用sys_call_table，和1實質相同，只是情況1更加明確。

第三 只配置CONFIG_AEABI 系統中不存在 sys_oabi_call_table，對old ABI方式調用不兼容。只能 以EABI方式調用，用sys_call_table

第四 兩個都沒有配置 系統默認會只允許old ABI方式，但是不存在old_syscall_table，最終會通過sys_call_table 完成函數調用

可以參考下面的代碼

對我們的項目比較有用。

.align 5

ENTRY(vector_swi)

sub sp, sp, #S_FRAME_SIZE

stmia sp, {r0 - r12} @ Calling r0 - r12

add r8, sp, #S_PC

stmdb r8, {sp, lr}^ @ Calling sp, lr

mrs r8, spsr @ called from non-FIQ mode, so ok.

str lr, [sp, #S_PC] @ Save calling PC

str r8, [sp, #S_PSR] @ Save CPSR

str r0, [sp, #S_OLD_R0] @ Save OLD_R0

zero_fp

#if defined(CONFIG_OABI_COMPAT)

#ifdef CONFIG_ARM_THUMB

tst r8, #PSR_T_BIT

movne r10, #0 @ no thumb OABI emulation

ldreq r10, [lr, #-4] @ get SWI instruction

#else

ldr r10, [lr, #-4] @ get SWI instruction

A710( and ip, r10, #0x0f000000 @ check for SWI )

A710( teq ip, #0x0f000000 )

A710( bne .Larm710bug )

#endif

#elif defined(CONFIG_AEABI)

A710( ldr ip, [lr, #-4] @ get SWI instruction )

A710( and ip, ip, #0x0f000000 @ check for SWI )

A710( teq ip, #0x0f000000 )

A710( bne .Larm710bug )

#elif defined(CONFIG_ARM_THUMB)

tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs

addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in

ldreq scno, [lr, #-4]

#else

ldr scno, [lr, #-4] @ get SWI instruction

A710( and ip, scno, #0x0f000000 @ check for SWI )

A710( teq ip, #0x0f000000 )

A710( bne .Larm710bug )

#endif

#ifdef CONFIG_ALIGNMENT_TRAP

ldr ip, __cr_alignment

ldr ip, [ip]

mcr p15, 0, ip, c1, c0 @ update control register

#endif

enable_irq

get_thread_info tsk

adr tbl, sys_call_table @ load syscall table pointer

ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing

#if defined(CONFIG_OABI_COMPAT)

bics r10, r10, #0xff000000

eorne scno, r10, #__NR_OABI_SYSCALL_BASE

ldrne tbl, =sys_oabi_call_table

#elif !defined(CONFIG_AEABI)

bic scno, scno, #0xff000000 @ mask off SWI op-code

eor scno, scno, #__NR_SYSCALL_BASE @ check OS number

#endif

stmdb sp!, {r4, r5} @ push fifth and sixth args

tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?

bne __sys_trace

cmp scno, #NR_syscalls @ check upper syscall limit

adr lr, ret_fast_syscall @ return address

ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine

add r1, sp, #S_OFF

2: mov why, #0 @ no longer a real syscall

cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)

eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back

bcs arm_syscall

b sys_ni_syscall @ not private func

__sys_trace:

mov r2, scno

add r1, sp, #S_OFF

mov r0, #0 @ trace entry [IP = 0]

bl syscall_trace

adr lr, __sys_trace_return @ return address

mov scno, r0 @ syscall number (possibly new)

add r1, sp, #S_R0 + S_OFF @ pointer to regs

cmp scno, #NR_syscalls @ check upper syscall limit

ldmccia r1, {r0 - r3} @ have to reload r0 - r3

ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine